오토핫키 강좌 (초보편 #02 )

이전 강좌에서는 메세지를 출력하고 그것을 활용하는 간단한 부분에 대해서 살펴 보았습니다.

오늘은 조건문, 반복문 등등에 뼈대 부분을 공부해볼까 합니다. 사실 명령어나 함수들은 레퍼런스를 통해서 얼마든지 따로 공부할 수 있는 부분이라 아직 응용은 안되더라도 기본 골자를 우선으로 하겠습니다.

1. 루프 (반복문) Loop

오토핫키에서는 다수의 방식을 제공하고 있습니다. 고급언어 (C,C++,Delphi, Java) 들도 반복문을 제공하지만 오토핫키의 loop 처럼 사용할려면 복잡한 코딩을 거쳐야만 가능합니다.

예를 들어서 for 문을 보면 for (i = 0; i < 10; i++){ ... } 과 같은 몇번 반복해라 이구문도 오토핫키에서는 Loop, 3 으로 끝나게 됩니다. 또 다른 예를 들면 해당 폴더의 폴더갯수나 폴더의 파일 갯수가 몇개인지를 알아내서 그 갯수만큼 루프를 돌려라 이런 기능을 수행할려면 복잡한 과정을 거쳐야만 가능하지만 오토핫키는 한줄로 그 기능을 수행합니다.  아래 예를 살펴보겠습니다.

[일반루프]

Loop  ; 무할루프를 돕니다. (아무것도 정해지지 않으면 여기에  Loop[, Count] 처럼되면 그 갯수만큼만 루프)

{

  if A_Index >= 10  ; 루프가 10 번을 돌거나 넘어서면 ...

    break  ; 현재 루프를 빠져나와라

}

※ 여기서 A_Index 라는 것이 나왔습니다.  현재 루프가 몇번째 인지 카운터 되는 편입변수 입니다.

    편입변수에는 정말 다양한 변수들이 내정되어 있습니다. 차후 강좌에서 따로 다루던지 매번 나오는 예제에는 웬만하면 

    사용됩니다.

[폴더나 파일갯수 만큼 루프]

Loop , %A_ProgramFiles%\*.txt, , 1  ; 이 옵션은 프로그램파일 폴더의 서브폴더 까지 모두 포함

{

  FileTxtList = %FileTxtList%`n%A_LoopFileFullPath%  ; FileTxtList 라는 변수에 확인한 파일을 계속 적재 한다.

  MsgBox, 4, , Filename = %A_LoopFileFullPath%`n`n 계속?  ; 확인한 파일을 보여주고 중지할 것인지 묻는다.

  IfMsgBox, No                                                                ;  이 부분은 전번 강좌에 있으므로 ...

      break                                                                        ; 안보겠다면 중지한다.

}

Msgbox, %FileTxtList%    ;  적대된 파일을 MsgBox 창으로 보여준다.. 너무 많으면  무리가 있으므로 적당히...

※ %A_ProgramFiles% 편입변수 시스템드라이브의 C:\Program Files 를 결과적으로 가르킨다.

    끝에 1  옵션이 서브폴더 모두라는 명령어 옵션이다. 이번 기회에 모든 JPG 파일을 검색해서 파일로 

    담아보도록 하겠습니다.

특정 시스템의 JPG 이미지를 찾아서 파일 목록을 파일로 저장해보겠습니다.

아래 소스는 원하는 위치의 서브디렉토리에서 해당 파일을 찾아서 파일로 저장합니다.

소스는 더보기를 클릭하세요

/* ----------------------------------------------------------------------------------
SingleInstance 는 실행중의 스크립트가 또 하나 기동되었을 때, 
「기존의 프로세스를 종료해 기동할까」를 문의하는 다이얼로그가 표시해, 「네」라고 
대답하면 기존의 프로세스를 종료해 새롭게 실행을 개시한다.「아니오」라고 대답하면, 
아무것도 하지 않고 종료한다.
---------------------------------------------------------------------------------- */
#SingleInstance force

; 처음 LOOP 를 돌리고 싶지 않다고 변수에 0 을 입력합니다.
loopchk = 0

main: ; 오토핫키는 처음 실행하게 되면 첫 번째 엘리멘트를 실행하고자 합니다.
return ; 그래서 아무것도 없는 빈 엘리멘트를 하나 만들었니다.

loopimg: ; 실질적인 작업을 담당하는 엘리멘트 입니다.
Loop, %A_ProgramFiles%\*.jpg, , 1 ; 서브디렉토리에서 jpg 이미지를 찾는거죠
{ ; A_ProgramFiles로 하면 용량에 무리가 있을 수 있습니다.
    if loopchk = 0 ; 실행하게 되면 1 이 되어서 루프가 돌지만 0 이면 중지 
    {
tooltip, ; 화면에 뿌려주던 메시지를 종료와 함께 보이지 않게 한다
        break
    }
    tooltip, %A_index% : %A_LoopFileFullPath% ; 현재 검출한 파일의 경로와 이름을 보여준다
/* ------------------------------------------------------------------------------
부연설명을 하자면 FileAppend 명령어가 해당 파일에 저장명령어 입니다.
저장하고자 하는 파일이 없으면 만들어서 저장합니다.
------------------------------------------------------------------------------ */
    FileAppend, %A_LoopFileFullPath%`n, %A_Scriptdir%\%A_Scriptname%.txt
}
return

/* ----------------------------------------------------------------------------------
+ : Shift
^ : Ctrl
---------------------------------------------------------------------------------- */
~+^F11:: ; 실행합니다. Ctrl + Shift + F11 으로 실행
loopchk=1
FileDelete, %A_Scriptdir%\%A_Scriptname%.txt
goto, loopimg
return

~+^F12:: ; 중지합니다. Ctrl + Shift + F12 으로 중지
loopchk=0
goto, loopimg
return

~+^F10:: ; 종료합니다. Ctrl + Shift + F10 으로 프로그램을 완전 종료
EXIT:
ExitApp
return

[문자열에 따른 루프]

예제 #1

Colors = red,green,blue

Loop, parse, Colors, `,

{

    MsgBox, Color number %A_Index% is %A_LoopField%.

}

※ 여기서 전역변수 %A_LoopField% 는  예를 들어서 설명하자면  배열의 필드 값입니다.

    메세지는 순서적으로 red,green,blue  를 출력할 것입니다.

예제 #2

Loop, read, C:\Database Export.csv ; 주소록 파일을 연다

{

    LineNumber = %A_Index% ; 현재 라인의 번호

    Loop, parse, A_LoopReadLine, CSV ; 현재 라인의 데이터를 나눈다.(파셔)

    {

        ; A_LoopField (편입변수) 는 나누어진 값

        MsgBox, 4, , Field %LineNumber%-%A_Index% is : `n %A_LoopField% `n`n Continue?

        IfMsgBox, No  ; 그만보겠다면 빠져나간다

            return  

    }

}

※ 네이버의 주소록 내보내기로 (naver_addr.csv) 작업해보면 직접 눈으로 확인 가능합니다.

    01. 이름(네이버),

    02. 이메일,

    03. 휴대폰,

    04. 집전화번호,

    05. 개인홈페이지,

    06. 회사/학교,

    07. 회사팩스,

    08. 회사전화,

    09. 부서/학과명,

    10. 회사주소,

    11. 집주소,

이런 순서대로 각 필드의 값을 출력합니다.

예제 #3

Loop, read, naver_addr.csv

{

    Loop, parse, A_LoopReadLine, %A_Tab%

    {

        MsgBox, 4, , Field number %A_Index% is %A_LoopField%.

        IfMsgBox, No

            return

    }

}

※ 줄단위의 데이터를 출력합니다.

---

오늘은 반복문에 대해서 공부를 해보았습니다.

오늘은 중간 중간 어려운 부분이 많았다고 보는데 어떠신지 모르겠습니다. 완전 이해가 아니라도 어느정도의 감만 챙기셔도 오늘은 충분히 잘한거라고 봅니다.

더 다양한 예제들도 많치만 아직은 보면 더 헷갈릴 수 있으니 차차 또 배워가도록 하는게 좋겠습니다.