SplashImage Maker - WYSIWYG

If you remember my SplashImage Sizer script here, then you'll know what this one is about.

Accept it! ..Splash windows look cool, and are useful too. But sizing them right to fit the maintexts, subtexts, images etc. and then making them look good is time consuming... so here's something to help u. Use this script to put in Text for Splash and size it using arrow keys... and when u get it right, press escape and the cmd reqd will be copied to clipboard... simple!... Its completely "what you see is what you get"

Hint : Keeping the window Title field blank generates a Splash without window titlebar (looks nice).

invalid-file

;The step-size per change (in pixels)
Step = 5

Gui, Add, Text, x6 y5 w100 h20, Window Title
Gui, Add, Text, x6 y55 w100 h20, Main Text
Gui, Add, Text, x6 y125 w100 h20, Picture
Gui, Add, Text, x6 y175 w100 h20, Sub Text

Gui, Add, Edit, x6 y25 w220 h20 vSTitle,
Gui, Add, Edit, x6 y75 w220 h40 vMText,
Gui, Add, Edit, x6 y145 w180 h20 ReadOnly vPicFile,
Gui, Add, Button, x196 y145 w30 h20, ..
Gui, Add, Edit, x6 y195 w220 h40 vSText,

Gui, Add, Button, x36 y245 w60 h20 Default, OK
Gui, Add, Button, x136 y245 w60 h20, Cancel

Gui, Show, x255 y75 h276 w233, Splasher
Return

ButtonCancel:
GuiClose:
   ExitApp


Button..:
   FileSelectFile, SelFile,,, Select Picture File
   GuiControl,, PicFile, %SelFile%
Return


ButtonOk:
   Gui, Submit
   SWidth = 150
   SHeight = 100
   IfEqual, STitle,
      Options = B1
   SplashImage,%PicFile%, W%SWidth% H%SHeight% %Options%,%SText%,%MText%,%STitle%
   HotKey, Up, Up
   HotKey, Down, Down
   HotKey, Left, Left
   HotKey, Right, Right
   HotKey, Esc, Esc
Return


Up:
   IfGreaterOrEqual, SHeight, %Step%
      SHeight -= %Step%
   SplashImage,%PicFile%, W%SWidth% H%SHeight% %Options%,%SText%,%MText%,%STitle%
Return


Down:
   SHeight += %Step%
   SplashImage,%PicFile%, W%SWidth% H%SHeight% %Options%,%SText%,%MText%,%STitle%
Return


Left:
   IfGreaterOrEqual, SWidth, %Step%
      SWidth -= %Step%
   SplashImage,%PicFile%, W%SWidth% H%SHeight% %Options%,%SText%,%MText%,%STitle%
Return


Right:
   SWidth += %Step%
   SplashImage,%PicFile%, W%SWidth% H%SHeight% %Options%,%SText%,%MText%,%STitle%
Return


Esc:
   SplashImage, Off
   StringReplace, MText, MText, `n, ``n, A
   StringReplace, SText, SText, `n, ``n, A
   SetEnv, ClipBoard, SplashImage`, %PicFile%`, W%SWidth% H%SHeight% %Options%`, %SText%`, %MText%`, %STitle%`n
   StringReplace, ClipBoard, ClipBoard, %A_Space%`,, `,, A
   SplashTextOn, 273, 46, Done!, The required command is copied to ClipBoard.
   Sleep, 500
   ExitApp
Return