SplashText Sizer - WYSIWYG

Even after tooltips and traytips I find myself using SplashText sometimes. Traytips are always in short supply, no matter how many apps try, only one can use it at a time. And SplashText is always more attention grabbing than Tooltips. But its usually a pain to use trial & error for sizing it just right, as it doesn't auto-size itself like tool/tray tips.

Use this script to put in Title and Text for SplashText and size it using arrow keys... and when u get it right, press escape and the cmd reqd will be copied to clipboard... simple!... Its completely "what you see is what you get" (I guess SmartGUI is spoiling me! )

invalid-file

;The step-size per change (in pixels)
Step = 5

; Generated by SmartGUI Creator 3.0
Gui, Add, Edit, x6 y7 w250 h20 vSTitle, Title
Gui, Add, Edit, x6 y37 w250 h130 vSText, Text
Gui, Add, Button, x46 y177 w70 h20 Default, Ok
Gui, Add, Button, x136 y177 w70 h20, Cancel
Gui, Show, h206 w265, Enter SplashText Here:
Return


ButtonCancel:
GuiClose:
   ExitApp


ButtonOk:
   Gui, Submit
   gosub, DynamicSplash
   
   SWidth = %len%
   SHeight = %lines%
   SplashTextOn, %SWidth%, %SHeight%, %STitle%, %SText%
   HotKey, Up, Up
   HotKey, Down, Down
   HotKey, Left, Left
   HotKey, Right, Right
Return


Up:
   IfGreaterOrEqual, SHeight, %Step%
      SHeight -= %Step%
   SplashTextOn, %SWidth%, %SHeight%, %STitle%, %SText%
Return


Down:
   SHeight += %Step%
   SplashTextOn, %SWidth%, %SHeight%, %STitle%, %SText%
Return


Left:
   IfGreaterOrEqual, SWidth, %Step%
      SWidth -= %Step%
   SplashTextOn, %SWidth%, %SHeight%, %STitle%, %SText%
Return


Right:
   SWidth += %Step%
   SplashTextOn, %SWidth%, %SHeight%, %STitle%, %SText%
Return


Esc::
   SplashTextOff
   StringReplace, SText, SText, `n, ``n, A
   SetEnv, ClipBoard,  SplashTextOn`, %SWidth%`, %SHeight%`, %STitle%`, %SText%`n
   SplashTextOn, 273, 46, Done!, The required command is copied to ClipBoard.
   Sleep, 500
   ExitApp
Return



DynamicSplash:
   setenv, charspace, 7 ;set space taken per character in text here
   setenv, linespace, 21 ;set space taken per line here

   StringSplit, piece, stext, `n
   setenv, len, 0

   Loop, %piece0%
   {
      StringLen, len0, piece%A_Index%
      ifgreater, len0, %len%, setenv, len, %len0%
   }
   setenv, lines, %piece0%
   envmult,len, %charspace%
   envmult,lines, %linespace%
   
   envadd, len, 10
Return